FindExactSpawnID and TargetExact, finding spawns by name

[blueninja]

FindExactSpawnID will return the spawn id of the spawn that matches the exact name passed to it, TargetExact will target the spawn matching the exact name.

The reason for this is that if you have two players with names that contain the same string, for example you have a toon Joe and a second toon Joey and you want to target Joe. Typing '/target joe' will target joey if he happens to be closer to you. These will match Joe no matter what.

Code: Select all

Sub FindExactSpawnID(string Name)
	/declare CurrentID int local
	/declare FirstID int local
	/declare Counter int local 1

	/varset CurrentID ${Spawn[${Name}].ID}
	
	:FESI_FindNext
		/if (!${CurrentID} || ${Spawn[id ${CurrentID}].CleanName.Equal[${Name}]}) /return ${CurrentID}
		/varset CurrentID ${Spawn[id ${Me.ID}].NearestSpawn[${Counter},${Name}].ID}
		/varcalc Counter ${Counter}+1
	/goto :FESI_FindNext
	
/return 0

Code: Select all

Sub TargetExact(string Name)
	/declare CurrentID int local
	/declare FirstID int local
	/declare Counter int local 1
	/varset CurrentID ${Spawn[${Name}].ID}
	
	:TE_FindNext
		/if (!${CurrentID}) /return 0
		/if (${Spawn[id ${CurrentID}].CleanName.Equal[${Name}]}) {
			/target id ${CurrentID}
			/return
		}
		/varset CurrentID ${Spawn[id ${Me.ID}].NearestSpawn[${Counter},${Name}].ID}
		/varcalc Counter ${Counter}+1
	/goto :TE_FindNext
	
/return

[SukMage]

That's great... I did notice that problem a few times but it's generally when grabbing a toon to CoH. Generally I know the people who I cross zone target/CoH and I would /tar joe and get joey then /tar clr joe and get the right one... That's not 100% effective but close to 80%. :) Thanks for the great sub to play with.

[Gameross]

Have the routine return a NULL if nothing found or the targets ID. Below is the code to do that. You can access the returned value via ${Macro.Return}

Thanks for the routine, took care of a targetting issue I was having with a macro I've been working on and was a low priority to get fixed.

Code: Select all

Sub TargetExact(string Name)
   /declare CurrentID int local
   /declare FirstID int local
   /declare Counter int local 1
   /varset CurrentID ${Spawn[${Name}].ID}

   :TE_FindNext
      /if (!${CurrentID}) /return NULL
      /if (${Spawn[id ${CurrentID}].CleanName.Equal[${Name}]}) {
         /target id ${CurrentID}
         /return ${CurrentID}
      }
      /varset CurrentID ${Spawn[id ${Me.ID}].NearestSpawn[${Counter},${Name}].ID}
      /varcalc Counter ${Counter}+1
   /goto :TE_FindNext

Yes, I didn't post the unneccesary /return as this should never reach it.

[blueninja]

Ok, good point, changed the post above.

Oh and yes, I know the /return never would be reached, for some reason I always end a sub with /return no matter what, probably because I think it looks better. :)