Attack and Bind

[ml2517]

These two macros are designed to attack and bind your PC's to raise their bind wound skill. (I haven't had time to really test it much so please tell me if you run into problems.)


1. Modify the ATTACKER and ATTACKEE definitions in the top of the scripts to the name of the appropriate players.
2. Go to an area away from NPC's that are going to be pissed if you are fighting other PC's.
3. Load up the guy running the bind.mac script with bandages.
4. /duel the attackee from the attacker.
5. /duel the attacker from the attackee.
6. Turn the attackee's back to the attacker (To avoid the attacker getting damage from riposts).
7. /macro bind.mac on the attackee
8. /macro attack.mac on the attacker

Babysit it for the first few cycles to make sure I didn't fubar something. If all is well file your nails while it does its thing.

This script should abort on both characters when you run out of bandages.

Code: Select all

| 
|  Bind.mac 
| 
| This script waits til he is around 30 percent health then starts bandaging himself. 
| Once he gets to around 50 percent health he waits til he gets down to 30 percent health again.  Rinse repeat.  
| When you run out of bandages he ends the macro. 
| 
#turbo 20 

| Change Gonzo to the player attacking you. 
#define ATTACKER Gonzo 

#Event OOBandages "You can't bandage without bandages" 

Sub Main 
:WaitForDamage 
/delay 1s 
/if n $char(hp,pct)<32 /call Bind 
/doevents 
/goto :WaitForDamage 
/return 

Sub Bind 
:BindWounds 
/if "$target(name,clean)"!="$char(name,clean)" /target myself 
/if n $char(ability,"Bind Wound")>0 /doability "Bind Wound" 
/delay 1s 
/doevents 
/if n $char(hp,pct)<50 /goto :BindWounds 
/return 

Sub Event_OOBandages 
/tell ATTACKER stopit 
/endmacro 
/return 

Code: Select all

|  Attack.mac 
| 
| This script attacks the target to 30 percent health.  
| Pauses until other targets health gets back up to 50 percent then 
| repeats.  If he gets a tell from ATTACKEE of stopit he will end the macro. 
| 

#turbo 20 
#chat tell 

| Change Bonzo to whatever the playername your victim is. 
#define ATTACKEE Bonzo 

Sub Main 
:TargetPC 
/target ATTACKEE 
/delay 1s 
/doevents 
/if "$target(name,clean)"!="ATTACKEE" { 
    /echo I can't target ATTACKEE.  Aborting script. 
    /endmacro 
} 

:CheckDistance 
/if $target()==FALSE /goto :TargetPC 
/call GetClose 

/if n $target(hp,pct)>=50 /attack on 
/if n $target(hp,pct)<=30 /attack off 

/doevents 
/goto :CheckDistance 
/return 

Sub GetClose 
/face nolook fast 
/if n $target(distance)>10 { 
   /press up 
} 
/if n $target(distance)<6 { 
   /press down 
} 
/doevents 
/return 

Sub Event_chat(MsgType,MsgFrom,MsgText) 
/if @MsgType==tell { 
    /if @MsgFrom==ATTACKEE /if @MsgText=="stopit" { 
    /attack off 
    /endmacro 
} 
/return