pick.mac. Makes/hands in Forged picks for Tribute - 7.4.04

[EQBot_man]

This Macro is useless as of the 7.17.2004 patch due to the fact that Forged Picks no longer sell for ~375 favor each. They now sell for 3 favor. But feel free to pick apart the code for use with vendors or whatever

I made this relativly complicated macro to give me tons of free tribute while I sleep. I can usually get like 20K tribute before you get stuck on a wall or crash or something. As you may knowmaking Forged Picks give you like 330 tribute per pick for like 2pp each. This is kinda an exploit until they fix it, so exploit as much tribute as you can before they do!

Here is what thie macro does:
You start out in front of Glenda in PoK and run the macro.
You run around picking stuff up that's needed to make the forged pick.
Then you combine them
Then you run to the Neriak Tribute master, and hand them in for 300tribute a pop
Then you Gate, and run back to Glenda
Repeat

Now several things have to line up in order for this macro to work and it will most likely require some tweaking on your part to get it to work for you.
1. You can't be KoS in Neriak (well that rules a lot of people out right away, oh well not my problem, fix the code)
2. You have to be able to cast the spell Gate (Or make new code to run you from Neriak Tribute master to Glenda, which again requires you to rewrite portions of the code.
3. You can't be floating. It messes up the pathing sometimes
4. you can change the number of picks you want to make at a time in a varset. For every pick you want to make you have to have 2 slots open.
5. The backpacks Where the picks wind up have to be in the first slot. For example. The way the script is now, have to empty backpacks in the first pack and 2nd pack slots and you will be fine
6. If you are an ogre you may have some trouble fitting through the door in Neriak
7. Stock yourself up with money before you go, Picks are like 3pp each, so..you won't need more than even 500pp.
8. If you try to use this macro the way it is written it will prolly fail cause its designed for ME, and I can gate, and I'm not KOs in Neriak and I'm small. So take it as is, but I guarentee it works for me.
9. oh I'm bound right outside the building that the PoK book is in in PoTranquility.
10. And you have to have at least a 50skill in Blacksmithing

So to sum this all up: Have two empty backpacks, don't be a big race, don't be KoS in Neriak, don't be floating, Have like 500pp on yourself,be a class that can cast Gate and be bound outside the building that the PoK book is in, in PoTranquility. Be a DE wizard necro or mage, and you'll be fine :)

Have fun modifying the code so it works for you.

Code: Select all

| pick.mac
|	by: EQBot_Man 7.4.04
|
|  /macro pick
|
|
|
|Here is what thie macro does:
|You start out in front of Glenda in PoK and run the macro.
|You run around picking stuff up that's needed to make the forged pick.
|Then you combine them
|Then you run to the Neriak Tribute master, and hand them in for 300tribute a pop
|Then you Gate, and run back to Glenda
|Repeat
|
|Now several things have to line up in order for this macro to work and it will most
|	likely require some tweaking on your part to get it to work for you.
|1.  You can't be KoS in Neriak (well that rules a lot of people out right away,
|	oh well not my problem, fix the code)
|2.  You have to be able to cast the spell Gate (Or make new code to run you from
|	Neriak Tribute master to Glenda, which again requires you to rewrite portions
|	of the code.
|3.  You can't be floating.  It messes up the pathing sometimes
|4. You can change the number of picks you want to make at a time in a varset.
|	For every pick you want to make you have to have 2 slots open.
|5.  The backpacks Where the picks wind up have to be in the first slot. For example.
|	The way the script is now, have to empty backpacks in the first pack and 2nd
|	pack slots and you will be fine
|6.  If you are an ogre you may have some trouble fitting through the door in Neriak
|7. Stock yourself up with money before you go, Picks are like 3pp each, so..you won't
|	need more than even 500pp.
|8. If you try to use this macro the way it is written it will prolly fail cause its
|	designed for ME, and I can gate, and I'm not KOs in Neriak and I'm small.
|	So take it as is, but I guarentee it works for me.
|9. oh I'm bound right outside the building that the PoK book is in in PoTranquility.
|
|So to sum this all up:
|	Have two empty backpacks, don't be a big race, don't be KoS in Neriak,
|   don't be floating, Have like 500pp on yourself,be a class that can cast Gate and
|   be bound outside the building that the PoK book is in, in PoTranquility.  Be a DE
|   wizard necro or mage, and you'll be fine :)
#include move.inc
#include Travel.inc
#Event busy "Someone else is using that#*#"
#Event nomore "#*#you don't have everything you need for this recipe#*#"
#Event DoneLoading "#*#You have entered#*#"
Sub Main

/deletevar finish
/deletevar failure
/deletevar busy
/deletevar LoadingBit
/deletevar NumberToMakeAtATime
/declare finish int global
/declare failure int global
/declare busy int global
/declare LoadingBit int global
/declare NumberToMakeAtATime int global
/varset failure 0
/varset finish 0
/varset busy 0
/varset LoadingBit 0

|--- Set the number of picks to make at a time ---|
/varset NumberToMakeAtATime 10
|------------------------------------------------
/echo Making ${NumberToMakeAtATime} picks at a time
:Continue
/call BuyMold
/call GlenaToTallis
/call BuyShaft
/call Tallistoglena
/call GlenaToWater
/call BuyWater
/call WaterToSheet
/call BuySheet
/call MoveToFirstForge
/call OpenForge
/call ForgeToTribute
/call Tribute
/call toPoT
/call PoTtoPoK
/call PoKtoGlena

/goto :Continue

/return


|=============================================
Sub BuyMold
/declare ForLoop int local
/echo Buying ${NumberToMakeAtATime} Molds
/target glen
/face fast
/click right target
/delay 2s
/itemnotify Merchant20 leftmouseup
/for ForLoop 1 to ${NumberToMakeAtATime}
/delay 15
/buyitem 1
/next ForLoop
/delay 15
/return
|=============================================
Sub BuySheet
/echo Buying ${NumberToMakeAtATime} Sheets of Metal
/target kale
/face fast
/click right target
/delay 2s
/itemnotify Merchant3 leftmouseup
/delay 15
/buyitem ${NumberToMakeAtATime}
/delay 15
/return
|=============================================
Sub BuyWater
/echo Buying ${NumberToMakeAtATime} Flasks of Water
/target Vuli
/face fast
/click right target
/delay 2s
/itemnotify Merchant6 leftmouseup
/delay 15
/buyitem ${NumberToMakeAtATime}
/delay 15
/return
|=============================================
Sub Buyshaft
/echo Buying ${NumberToMakeAtATime} Oak Shafts
/declare ForLoop int local

/target tallis
/face fast
/click right target
/delay 2s
/itemnotify Merchant9 leftmouseup

/for ForLoop 1 to ${NumberToMakeAtATime}
/delay 15
/buyitem 1
/next ForLoop
/delay 15
/return
|=============================================
Sub OpenForge
/echo Combineing Items to Make Forged Pick
:Forge
/itemtarget forge
/face fast nolook
/click left item
/delay 2s
	/if (!${Window[TradeskillWnd].Open}) {
		/echo Someone is using the Forge waiting 10seconds then trying again
		/delay 10s
		/goto :Forge
	}
/notify COMBW_RecipeListArea COMBW_RecipeList listselect ${Window[COMBW_RecipeListArea].Child[COMBW_RecipeList].List[=Forged Pick]}

:CombineLoop
/notify COMBW_CombineArea COMBW_CombineButton leftmouseup
/delay 5
/autoinventory
/doevents
/if (${finish}==1) {
	/varset finish 0
	/return
}
/goto :CombineLoop
/delay 15
/keypress esc
/delay 5
/keypress esc
/return
|=============================================
Sub Event_busy
/varset busy 1
/return
|=============================================
Sub Event_nomore
/varset finish 1
/return
|=============================================
Sub Tribute
/echo Handings things into Tribute Master
/declare ForLoop int local
/target nert
/face fast
/click right target
/delay 2s

/itemnotify pack1 rightmouseup
/delay 1s
|----
/for ForLoop 1 to ${NumberToMakeAtATime}

/itemnotify in pack1 ${ForLoop} leftmouseup
/if (!${SelectedItem.ID}==21540) {
	/if (${String[${SelectedItem.ID}].Find["NULL"]}>0) {
		/echo You failed a combine I think
	} Else {
	/echo Something messed up ending macro. .
	/endmacro
	}
}

/notify TributeMasterWnd TMW_DonateButton leftmouseup
/delay 1s
/next ForLoop
/delay 15
/return
|=============================================

To be able to move around you need move.inc, which I've included a copy of here and I've changed some of the code around to be more reliable so its actully better than the one you'll find in the forums somewhere:

Code: Select all

|===================================================|
|- move.inc                                         |
|                                                   |
|Simple moving and object-avoidance routines        |
|                                                   |
|Originally by beatnik007 (Who credits Mckorr)      |
|                                                   |
|Revised and converted to MQ2Data by Terramantian   |
|						    |
|Improved upon by EQBot_Man   7.4.04		    |
|===================================================|


| Sub MoveToLoc                                     |
|---------------------------------------------------|
|This simply moves the player to within 10 units of |
|the requested location, while avoiding obstacles   |
|                                                   |
|This is beatnik007's original sub, with a few minor|
|changes and rewritten in MQ2Data format            |
|                                                   |
|SYNTAX: /call MoveToLoc Y X                        |


Sub MoveToLoc(MoveToY, MoveToX)
    |/echo Moving to Location: ${MoveToY}, ${MoveToX}.
    |/echo Distance: ${Math.Distance[${Me.Y},${Me.X}:${MoveToY},${MoveToX}]}

    /declare running int local
    /declare MaxSpeed int local
    /declare StopDistance int local
    /declare distanceNow float local
    /declare distanceBefore float local
    /declare distanceModifier int local
    /varset running 0
    /declare distanceTimer timer 15
    /varset distanceBefore ${Math.Distance[${Me.Y},${Me.X}:${MoveToY},${MoveToX}]}
    /varset distanceModifier 1
    /varset MaxSpeed 0
    :moveToLocation

	/if (${Me.Speed}>=${MaxSpeed}) /varset MaxSpeed ${Me.Speed}
	/if (${MaxSpeed}<=151) {
		/varset StopDistance 3
	} else {
		/varset StopDistance 10
	}

    /face fast nolook loc ${MoveToY},${MoveToX}

    /if (${Math.Distance[${Me.Y},${Me.X}:${MoveToY},${MoveToX}]}<${StopDistance}) {
        /keypress forward
        /return
    }

    /if (${distanceTimer}==0) {
        /if (${Me.Sneaking}) {
            /varset distanceModifier 2
        } else {
            /varset distanceModifier 1
    	}

        /varset distanceNow ${Math.Distance[${Me.Y},${Me.X}:${MoveToY},${MoveToX}]}
        /if (${Math.Calc[${distanceBefore}-${distanceNow}]}<${Math.Calc[10/${distanceModifier}]}) {
      		/call strafePastObstacle
        }

        /varset distanceBefore ${Math.Distance[${Me.Y},${Me.X}:${MoveToY},${MoveToX}]}
        /varset distanceTimer 15
    }

    /if (${running}==0) {
        /keypress forward
        /if (${Math.Distance[${Me.Y},${Me.X}:${MoveToY},${MoveToX}]}>${StopDistance}) {
            /varset running 1
            /keypress forward hold
        }
    } else {
        /if (${Math.Distance[${Me.Y},${Me.X}:${MoveToY},${MoveToX}]}<${StopDistance}) {
            /varset running 0
            /keypress forward
        }
    }
    /goto :moveToLocation
/return


| Sub MoveToSpawn                                   |
|---------------------------------------------------|
|This moves the player to within a provided distance|
|of the provided spawn, while avoiding obstacles    |
|                                                   |
|I "wrote" this, but as you can see, it's the same  |
|as MoveToLoc with a few variable replacements.     |
|                                                   |
|The second parameter, Distance, allows for the     |
|player to stop short of the target by a certain    |
|amount, to provide for different aggro radii, etc. |
|                                                   |
|SYNTAX: /call MoveToSpawn ID Distance              |

Sub MoveToSpawn(MoveToID, StopDistance)

    /if (!(${Defined[MoveToID]})||(${Spawn[MoveToID].ID})) {
        /echo Spawn ID not found or no ID provided. Aborting...
        /return
    }
    /if (!(${Defined[StopDistance]})) {
   /echo Stopping point not defined, using default distance of 70
        /declare StopDistance int local
        /varset StopDistance 70
    }

    /echo Moving to Spawn: ${MoveToID} (${Spawn[${MoveToID}].CleanName}).
    /echo Current Location: ${Spawn[${MoveToID}].Y}, ${Spawn[${MoveToID}].X}
    /echo Current Distance: ${Spawn[${MoveToID}].Distance}

    /declare running int local
    /declare distanceNow float local
    /declare distanceBefore float local
    /declare distanceModifier int local
    /varset running 0
    /declare distanceTimer timer 15
    /varset distanceBefore ${Spawn[${MoveToID}].Distance}
    /varset distanceModifier 1

    :moveToSpawn

    /squelch /face fast nolook id ${MoveToID}

    /if (${Spawn[${MoveToID}].Distance}<${StopDistance}) {
        /keypress forward
        /return
    }

    /if (${distanceTimer}==0) {
        /if (${Me.Sneaking}) {
            /varset distanceModifier 2
        } else {
            /varset distanceModifier 1
        }

        /varset distanceNow ${Spawn[${MoveToID}].Distance}
        /if (${Math.Calc[${distanceBefore}-${distanceNow}]}<${Math.Calc[10/${distanceModifier}]}) {
      /call strafePastObstacle
        }
        /varset distanceBefore ${Spawn[${MoveToID}].Distance}
        /varset distanceTimer 15
    }

    /if (${running}==0) {
        /keypress forward
        /if (${Spawn[${MoveToID}].Distance}>=${StopDistance}) {
            /varset running 1
            /keypress forward hold
        }
    } else {
        /if (${Spawn[${MoveToID}].Distance}<${StopDistance}) {
            /varset running 0
            /keypress forward
        }
    }
    /goto :moveToSpawn
/return

| Only to be used by the previous functions - It's obvious what it does. |

sub strafePastObstacle
    /keypress forward
    /keypress back hold
    /delay 2
    /keypress back
    /if (${Math.Rand[99]}>50) {
        /keypress strafe_right hold
    } else {
        /keypress strafe_left hold
    }
    /delay 5
    /keypress strafe_right
    /keypress strafe_left
    /keypress forward hold
/return

Sub Turn(THeadingY,THeadingX)
   /declare PHeading outer 0
   /declare THeading outer 0
   /declare Bearing outer 0
   /declare IsTurning outer 0
   /declare TurnKey outer NULL

:TurnLoop
   /delay 0
   /if (${Me.Sitting}) /sit off
   /varset PHeading ${Me.Heading.Degrees}
   /if (${Defined[THeadingX]}) {
      /varset THeading ${Heading[${THeadingY},${THeadingX}].Degrees}
   } else {
      /varset THeading ${Target.HeadingTo.Degrees}
   }

   /varset Bearing ${Math.Calc[(${PHeading}-${THeading}+540)%360-180]}

   /if (${Bearing}>=-7 && ${Bearing}<=7) {
      /if (${String[${TurnKey}].NotEqual[NULL]}) /keypress ${TurnKey}
      /face heading ${Heading[${THeading}].Degrees} nolook
      /return
   } else /if (${Bearing}>=-180 && ${Bearing}>=7) {
      /if (${String[${TurnKey}].NotEqual[LEFT]}) /varset TurnKey LEFT
   } else /if (${Bearing}<=180 && ${Bearing}<=7) {
      /if (${String[${TurnKey}].NotEqual[RIGHT]}) /varset TurnKey RIGHT
   }

   /if (!${IsTurning}) {
      /keypress ${TurnKey} hold
      /varset IsTurning 1
   }
   /goto :TurnLoop

/return

And here is my ever growing Travel.mac which includes functions to move me around in other macros I have so a lot of the code is not used, but you can use it to make really simple /call macros to call the functions to move you to ldon or KT or Barindu with it take a look at it. It also includes some nice activate portals and open doors functions that are very reliably which I've wrote. Feel free to copy and paste them for your own code to open doors and activate portals( /call OpenDoor, /call AvtivatePortal), I feel they are pretty nice :)

Code: Select all

| travel.mac
|     by EQBot.Man 7.4.04
|
| To be used wtih move.inc
|
|===========================
Sub PoTtoPoK
/echo Moving from Bind Point to PoK
/look 0
/call MoveToLoc 706 -1333
/call MoveToLoc 726 -1432
/call MoveToLoc 769 -1436
/call ActivatePortal
/delay 5s
/return
|===========================
Sub PoKtoButcher
/echo Moving from PoK at PoT stone to Butcher Stone
/look 0
/call MoveToLoc 16 -231
/call MoveToLoc 244 -13
/call MoveToLoc 385 200
/call MoveToLoc 501 273
/call MoveToLoc 576 274
/call MoveToLoc 876 474
/call MoveToLoc 906 475
/call ActivatePortal


/return
|===========================
Sub ButchertoMagus
/echo Moving from the PoK book in BB to the Magus
/look 0
/call MoveToLoc 1458 -637
/call MoveToLoc 1007 -669
/call MoveToLoc 673 -626
/call MoveToLoc 9 -108
/call MoveToLoc -436 -22
/call MoveToLoc -701 -121
/call MoveToLoc -863 -244
/call MoveToLoc -936 -331
/call MoveToLoc -1202 -1121
/call MoveToLoc -1204 -1638
/call MoveToLoc -1113 -1931
/call MoveToLoc -1089 -2356
/call MoveToLoc -1101 -2418
/target magus
/face fast
/call MoveToLoc -1076 -2461
/return
|===========================
Sub MagustoNatimbi
/echo Moving from Magus to Natimbi
/look 0
/target magus
/face fast
/delay 2
/keypress h
/delay 3s
/say Nedaria's Landing
/delay 3s
/say Nedaria's Landing
/delay 3s
/say Nedaria's Landing
/delay 10s
/call MoveToLoc 1055 1536
/call MoveToLoc 1011.25 1527
/target wenla
/face fast
/delay 5
/keypress h
/delay 3s
/say Natimbi
/delay 3s
/say Natimbi
/delay 3s
/say Natimbi
/delay 2s

/return
|================================
Sub OpenDoor

/echo Trying to Open a Door
:OpenDoor
/doortarget
/delay 5
/if (${String[${Switch.Open}].Find["FALSE"]}>0) {
	/if (${Target.Name.Find["door"]} && ${Target.Distance}<=12) {
	    /echo Opening Door. . .
	    /keypress USE HOLD
	    /keypress USE
	    /delay 1s
	    /if (${Target.Name.Find["door"]} && ${String[${Switch.Open}].Find["TRUE"]}>0) /return
	}
} Else {
	/if (${Target.Name.Find["door"]} && ${Target.Distance}<=12) {
	    /keypress USE HOLD
	    /keypress USE
	    /delay 4s
	}
}
/if (${Target.Distance}>12) {
/face fast nolook
/look 0
/delay 2
/keypress forward hold
/delay 1
/keypress forward
/delay 5
}
/goto :OpenDoor
/return
|=============================
Sub GlenaToWater
/echo Moving from Glenda Quok to The guy where you buy water
/look 0
/call MoveToLoc 131 353
/call MoveToLoc 119 213
/call MoveToLoc 16 217
/call MoveToLoc -17 246.68

/return
|===========================
Sub WaterToSheet
/look 0
/call MoveToLoc -30 215
/call MoveToLoc -138 218
/call MoveToLoc -483 454
/call MoveToLoc -500.8 543.7
/call MoveToLoc -468 545
/call OpenDoor
/call MoveToLoc -438 545
/call MoveToLoc -438 550
/return
|===========================
Sub MoveToFirstForge
/look 0
/keypress esc
/delay 5
/keypress esc
/call MoveToLoc -424 547
/call MoveToLoc -421 558

/return
|===========================
Sub ForgeToTribute

/echo Moving from the forge to the tribute person in Neriak
/look 0
/call MoveToLoc -421 545
/call MoveToLoc -463 543.5
/call OpenDoor
/call MoveToLoc -491.7 542.8
/call MoveToLoc -493.8 715.2
/call MoveToLoc -551 714.8
/call MoveToLoc -551 626.7
/call MoveToLoc -826.5 131.5
/call MoveToLoc -903.1 131.8
/call ActivatePortal

/call MoveToLoc 1092 -435.5
/call MoveToLoc 1111.8 -514.9
/call MoveToLoc 2122.8 -845
/call MoveToLoc 2307.3 -1009
/call MoveToLoc 2306 -1108
/call MoveToLoc 2265 -1103
/keypress forward hold
/delay 2s
/keypress forward
/delay 20s

/call MoveToLoc 2 154
/call MoveToLoc -9.2 -78.2
/call MoveToLoc 35.14 -69.24
/call MoveToLoc 35.3 -57.17
/call OpenDoor
/call MoveToLoc 35.4 -46.3
/call MoveToLoc 62.8 -45
/call MoveToLoc 58 -6
/call MoveToLoc 24 -8
/call MoveToLoc 24.4 -51.5
/call MoveToLoc 47.4 -26.8
/call MoveToLoc 47.6 -8.9



/return
|=============================

Sub ActivatePortal

/echo Attempting to activate portal
/declare TempZone string local ${Zone.Name}

:ActivatePortal

/doortarget

/delay 5

	/if (${Target.Distance}>12) {
		/face fast nolook
		/look 0
		/delay 2
		/keypress forward hold
		/delay 1
		/keypress forward
		/goto :ActivatePortal
	}
/doortarget
/delay 2
/Keypress USE hold
/delay 2
/Keypress U
	/doortarget
	/delay 2
	/face fast
	/keypress forward hold
	/delay 1
	/keypress forward
		/if (!${TempZone.Equal[${Zone.Name}]}) {
			/Keypress USE
			/delay 2s
			/return
		}
/doortarget
/delay 2
/Keypress USE hold
/delay 2
/Keypress U
/delay 2
		/if (!${TempZone.Equal[${Zone.Name}]}) {
			/Keypress USE
			/delay 2s
			/return
		}
/Call ClickFest

   /keypress pitchdown hold

   /keypress USE hold
   /delay 1
   /if (${TempZone.Equal[${Zone.Name}]}) {
   	/Keypress USE
   	/goto :ActivatePortal
   } Else {
   	/Keypress USE
   	/return
   }


/return
|=============================
Sub PoKtoGlena
/echo Moving from the PoT Stone in PoK to Glenda Quok
/call MoveToLoc -188 -51
/call MoveToLoc -188.5 358
/call MoveToLoc 66.9 347
/call MoveToLoc 76 326


/return
|===========================
Sub GlenatoTallis
/echo Moving from Glenda to Tallis
/call MoveToLoc -276.4 471
/call MoveToLoc -393.1 725.3
/call MoveToLoc -395.8 1172
/call MoveToLoc -189 1513
/call MoveToLoc -68.25 1511
/call MoveToLoc -71.18 1412.7
/call MoveToLoc 48.25 1409.73
/call MoveToLoc 48.12 1401.38
/call OpenDoor
/call MoveToLoc 48.77 1387
/call MoveToLoc 72.22 1390
/return
|===========================
Sub TallistoGlena
/echo Moving from Tallis to Glenda
/call MoveToLoc 48.77 1387
/call MoveToLoc 47.3 1396
/call OpenDoor
/call MoveToLoc 48.25 1409.73
/call MoveToLoc -71.18 1412.7
/call MoveToLoc -68.25 1511
/call MoveToLoc -189 1513
/call MoveToLoc -395.8 1172
/call MoveToLoc -393.1 725.3
/call MoveToLoc -276.4 471
/call MoveToLoc 69.7 348
/call MoveToLoc 74.5 327
/return
|===========================
Sub NatimbiToQinimi
/echo Moving from Natimbi to Qinimi
:DontMove
/if (!${Me.Levitating}) {
	/popup DMF Yourself
	/delay 2s
	/goto :DontMove
}
/if (!${Me.Invis}) {
	/popup Invis yourself
	/delay 2s
	/goto :DontMove
}

/look 10
/call MoveToLoc 624 -1295
/call MoveToLoc 1398 -345
/call MoveToLoc 1383 -111
/call MoveToLoc 1644 187
/call MoveToLoc 1749 185
/call MoveToLoc 1926 53
/call MoveToLoc 2035 56
/call MoveToLoc 2070 150
/keypress forward hold
/delay 3s
/keypress forward
/return
|===========================
Sub QinimiToBarindu
/echo Moving from Qinimi to Barindu
:DontMove
/if (!${Me.Invis}) {
	/popup Invis yourself
	/delay 2s
	/goto :DontMove
}

/call MoveToLoc 10.75 -1225.3
/call MoveToLoc -123 -1098
/call MoveToLoc -95.6 -913.7
/call MoveToLoc -51.1 -829.7
/call MoveToLoc -59.17 -745.4
/call MoveToLoc -177.77 -460.9
/call MoveToLoc 198 -393.5
/call MoveToLoc 302.5 -189
/call MoveToLoc 402.2 -229.5
/call MoveToLoc 644.4 245.5
/call MoveToLoc 550.85 290.3
/call MoveToLoc 586 369
/keypress forward hold
/delay 3s
/keypress forward
/return
|===========================
Sub BarinduToVxed
/echo Moving from Barindu to Vxed
:DontMove
/if (!${Me.Invis}) {
	/popup Invis yourself
	/delay 2s
	/goto :DontMove
}


/call MoveToLoc -1368 609
/call MoveToLoc -1454.88 566.3
/call MoveToLoc -1461 318.5
/call MoveToLoc -1763 179
/call MoveToLoc -1759 -263
/call MoveToLoc -1296 -267
/call MoveToLoc -1238 -354
/call MoveToLoc -1133 -359
/call MoveToLoc -1077 -268
/call MoveToLoc -670 -271
/call MoveToLoc -616 -371
/call MoveToLoc -505 -367
/call MoveToLoc -389 -694
/call MoveToLoc 39 -695
/call MoveToLoc 209 -1133
/call MoveToLoc 452.7 -1249
/call MoveToLoc 517.7 -1194
/return
|===========================
Sub toPoT
/echo Gating to Bind point
/keypress esc
/delay 2
/keypress esc
/delay 2
/keypress esc
/delay 2
/keypress esc
/stand
/delay 2s
/cast "Gate"
/delay 5
/cast "Gate"
/delay 5
/cast "Gate"
/delay 5
/cast "Gate"
/delay 12s
/cast "Gate"
/delay 10s
/return
|===========================
Sub NatimbiToKodTaz
/echo Moving from Natimbi Zone in to Kod'Taz
/popup Warning You may get aggro crossing this zone, and you may not actually zone into Kod'Taz, Please Click the Obelisk
/look 10
/call MoveToLoc 160 -50.9
/look 10
/call MoveToLoc 239.7 172
/call MoveToLoc 1324 1283
/call MoveToLoc 1115.6 1545.55
/doortarget
/face fast
/popup Warning You may have aggro, and you may not actually zone into Kod'Taz, Please Click the Obelisk

/call MoveToLoc 1140.6 1547.66
/popup Warning You may have aggro, and you may not actually zone into Kod'Taz, Please Click the Obelisk

/call ActivatePortal
/return
|============================
Sub ClickFest
/declare LoopX int local
/declare LoopY int local
/for LoopX 300 to 800 step 100
	/for LoopY 200 to 600 step 100
		/Click Left ${LoopX} ${LoopY}
	/next LoopY
/next LoopX

/return

[Bad Karma]

IS this is where we call in the dumbass police?

[demiourgos]

I dont know what Bad Karma's post means. I really like this macro, i ran it for a few hours and got 32k in tribute. It was slightly buggy in cacthing on doors, but other than that it works great. Not to mention i was able to macro a route from pok to BB ldon camp with the included travel.inc. Great work!

[PhoenixZorn]

I dont know what Bad Karma's post means.

Calling the Dumbass Police means this post should be locked or deleted because it is not only an AFK macro, but a PP/Tribute macro, both of which are not allowed on MQ boards...

[demiourgos]

I see, well someone delete this shit then.

[EQBot_man]

Really? Hmm well I didn't know that. Sorry.

Yeah it gets buggy around doors you kinda have to baby it but it works on the whole