MacroQuest64

Posted: **Fri Oct 29, 2004 12:46 am**

Updated Dec 30, 2004 - Removed most of the declares as they were totally unessicary as Cr4zy pointed out oh-so-long ago.

I obviously got the idea from the "perfect xp tracker" from the macro's section but the information it gave just wasn't what I was looking for so I rewrote most of it and gave it a different feel.

You'll have to set up the #event if you want to use it as an exp event or if you just want to /call it at a certain time you can do that as well, either way should work. Let me know any problems you run into.

Updated 10-29-04
Fixed a problem counting regular exp. Should count properly now.

Code: Select all

|**********************
Exp_Tracking.inc
Version 2.0

This include will track your exp in various forms.
You can track Total Exp Gained, Total AA Exp Gained, Total Run Time, Exp Gained Per Minute,
AA Exp Gained Per Minute, Aproximate Time Till Ding, and Aproximate Time Till AA Ding.
Some of this came from the current "perfect xptracker" macro however I wanted to display
more usefull information.

To use simply /call ExpPrep during a part of your macro that is only called once.
Then /call ExpTrack at any moment you wish to check your exp stats.
***********************|


Sub ExpPrep

   /declare Exper               float  outer ${Me.PctExp}
   /declare AAExp               float  outer ${Me.PctAAExp}
   /declare TotalAAExp          float  outer  0.00
   /declare TotalExp            float  outer  0.00

   
|*********************************************************************
Edit these values as you see fit. If you set to 1 the information will 
show each call. Set to 0 and it will not show.
**********************************************************************|

||Show Total Exp Gained?||
   /declare ShowTEG       bool   outer TRUE

||Show Total AA Exp Gained?||
   /declare ShowTAAEG     bool   outer TRUE
   
||Show Total Run Time?||   
   /declare ShowTRT       bool   outer TRUE
   
||Show Exp Gained Per Minute?||   
   /declare ShowEGPM      bool   outer TRUE
   
||Show AA Exp Gained Per Minute?||
   /declare ShowAAEGPM    bool   outer TRUE
   
||Show Aproximate Time Till Ding?||
   /declare ShowATTD      bool   outer TRUE
   
||Show Aproximate Time Till AA Ding?||
   /declare ShowATTAAD    bool   outer TRUE
   
/return

Sub ExpTrack

  /if (${Me.PctAAExp}>=${AAExp}) {
   /varset AAExp ${Math.Calc[${Me.PctAAExp}-${AAExp}]} 
  } else {
   /varset AAExp ${Math.Calc[${Me.PctAAExp}-${AAExp}+100]}
  }
  /if (${Me.PctExp}>=${Exper}) {
   /varset Exper ${Math.Calc[${Me.PctExp}-${Exper}]} 
  } else {
   /varset Exper ${Math.Calc[${Me.PctExp}-${Exper}+100]}
  }
      /varcalc TotalAAExp ${TotalAAExp}+${AAExp}
      /varcalc TotalExp ${TotalExp}+${Exper}

   /echo ***************************************
   /if (${ShowTEG}) /echo Total Exp Gained: ${TotalExp}%
   /if (${ShowTAAEG}) /echo Total AA Exp Gained: ${TotalAAExp}%
   /if (${ShowTRT}) /echo Total Running Time: ${Math.Calc[${Macro.RunTime}/60]} minutes
   /if (${ShowEGPM}) /echo Exp Gained Per Minute: ${Math.Calc[${TotalExp}/${Math.Calc[${Macro.RunTime}/60]}]}
   /if (${ShowAAEGPM}) /echo AAExp Gained Per Minute: ${Math.Calc[${TotalAAExp}/${Math.Calc[${Macro.RunTime}/60]}]}
   /if (${ShowATTD}) {
      /if (${TotalExp}==0) {
         /echo Aprox Time till Ding: Forever!!
      } else {
         /echo Aprox Time till Ding: ${Math.Calc[${Math.Calc[${Math.Calc[${Macro.RunTime}/60]}/${TotalExp}]}*${Math.Calc[100-${Me.PctExp}]}]} minutes
      }
   }
   /if (${ShowATTAAD}) {
      /if (${TotalAAExp}==0) {
         /echo Aprox Time till AA Ding: Forever!!
      } else {
         /echo Aprox Time till AA Ding: ${Math.Calc[${Math.Calc[${Math.Calc[${Macro.RunTime}/60]}/${TotalAAExp}]}*${Math.Calc[100-${Me.PctAAExp}]}]} minutes
      }
   }
   /echo ***************************************
   /varset Exper ${Me.PctExp} 
   /varset AAExp ${Me.PctAAExp} 
   
/return

Posted: **Thu Dec 30, 2004 4:29 pm**

Updated Dec 30, 2004

Posted: **Sat Jan 01, 2005 7:53 am**

Nice mac include. Has a bit of a bug though. It doesnt keep track of the number of aa's. Instead, it will report only the portion of the present aa your working on even if it has been running for 10 hours and got 10aa already. This will in turn skew the projected ding time to think it will take 30 more hours if your at 0.33 of an aa when you check it.
hehe

I suspect some simple fix is possible for this. =)

Posted: **Sat Jan 01, 2005 1:03 pm**

I'm not sure I know what you mean. If you have dinged 10 times this should be reporting 1000%+ AA Exp. That's how it works for me.

MacroQuest64

Exp_Tracking.inc --New and Improved Exp Tracker, as a .inc

Exp_Tracking.inc --New and Improved Exp Tracker, as a .inc