MacroQuest64

Need to talk about MacroQuest to other MacroQuest users?
https://mq64.org/phpBB3/

spellcast.inc - generic casting include file.

https://mq64.org/phpBB3/viewtopic.php?t=6748

Page 1 of 3

spellcast.inc - generic casting include file.

Posted: Thu Apr 29, 2004 2:06 pm
by ml2517
spellcast.inc

Code: Select all

|
| SpellCast.inc 
|
| Last Modified: 5/14/2004 9:30pm
| This will cast a spell reliably for you... 
| 
| Usage: 
|       /call Cast "spellname|itemname|AA#|AAskillname" [item|activate|gem#] [nocheck|dismount|nodismount]
|
| If no dismount or nodismount is provided it defaults to nodismount.
| 
| This would essentially: /cast "Death Peace" 
| example: /call Cast "Death Peace" 
| 
| This would essentially: Check for the spell in your spell slots, if not there mem it to spell 
|                         gem slot 7 and then /cast "Death Peace" 
| example: /call Cast "Death Peace" gem7
|
| This would essentially: /cast item "White Rope Bridle" 
| example: /call Cast "White Rope Bridle" item 
| 
| This would essentially: /alt activate 169
| example: /call Cast "169" activate 
|  or...
| example: /call Cast "Divine Arbitration" activate 
|
| This would dismount if your target was lost or dies mid-cast, cast Burn and mem it to spell
| slot 3 if it wasn't already memmed:
| example: /call Cast "Burn" gem3 dismount
|
| This would not dismount but would move you back and forth if your target was lost or dies mid-cast, cast Burn and mem
| it to spell slot 3 if it wasn't already memmed:
| example: /call Cast "Burn" gem3 nodismount
|
| 'nocheck' is the default for the "loss of target/target dying" value.  If nocheck is specified (Or nothing was specified)
| no target checking will be performed and spellcast.inc should act like the spellcast.inc of the past.
|
| It will return the following values: 
| CAST_SUCCESS 
| CAST_UNKNOWNSPELL 
| CAST_OUTOFMANA 
| CAST_OUTOFRANGE 
| CAST_CANNOTSEE 
| CAST_STUNNED 
| CAST_RESISTED 
| CAST_TOOK2LONG 
| CAST_ABILITYNOTREADY 
| CAST_IMMUNESLOW 
| CAST_LOSTTARGET
| 
| New Vars Modification 
| Plazmic's no globals needed version 
| 
| Oct 09, 2003 - Updated to work with new vars and $char(casting) -gf 
| Oct 11, 2003 - switched some logic, removed defines -gf 
| Oct 15, 2003 - Item support added by -EqMule 
| XXX xx, xxxx - Modified to add automeming of spells. -Goofmester1 
| Dec 26, 2003 - fd fail 1 added -m0nk 
| Jan 01, 2004 - timeout(5s) added to stop "dead-time" -m0nk 
| Jan 01, 2004 - switchd fdfail to a standing check. -m0nk 
| Jan 01, 2004 - added silence checking as a stun check -m0nk 
| Feb 17, 2004 - added AA activate capabilities -ml2517 
| Apr 11, 2004 - Updated for new Parm system -ml2517 
| Apr 12, 2004 - Will spit out a different message on immune to slows. -ml2517 
| Apr 16, 2004 - Removed /sendkeys and replaced with /keypress. -ml2517 
| Apr 17, 2004 - Various code enhancements. -Wassup 
| Apr 20, 2004 - Updated all of the /if's to have parenthesis. -ml2517 
| Apr 25, 2004 - Updated to new variable system. -ml2517 
| Apr 29, 2004 - Fixed Item problem -ml2517
| Apr 29, 2004 - Changed the alt ability to use AltAbilityReady instead of an event. -ml2517
| May 02, 2004 - Added the ability to specify a gem slot to mem spells to. -ml2517
| May 10, 2004 - Updated for new event system.
| May 12, 2004 - Added suggestions for loss of target and stun handling change. -ml2517
| May 13, 2004 - Activate now accepts AA skill by name or number. -ml2517
| May 14, 2004 - Added the nocheck value, it is the default. This bypasses the target checking code. -ml2517
| 

#event Fizzle "#*#Your spell fizzles#*#" 
#event Interrupt "#*#Your casting has been interrupted#*#" 
#event Interrupt "#*#Your spell is interrupted.#*#" 
#event Recover "#*#You haven't recovered yet...#*#" 
#event Recover "#*#Spell recovery time not yet met.#*#" 
#event Resisted "#*#Your target resisted the #*#" 
#event OutOfMana "#*#Insufficient Mana to cast this spell!#*#" 
#event OutOfRange "#*#Your target is out of range, get closer!#*#" 
#event NoLOS "#*#You cannot see your target.#*#" 
#event Stunned "#*#You cannot cast while stunned#*#" 
#event Stunned "#*#You *CANNOT* cast spells, you have been silenced!#*#" 
#event Standing "#*#You must be standing to cast a spell#*#" 
#event Standing "#*#has fallen to the ground.#*#" 
#event Collapse "#*#Your gate is too unstable, and collapses.#*#" 
#event ImmuneSlow "#*#Your target is immune to changes in its attack speed.#*#" 


Sub Cast(SpellName,ItemFlag,DismountFlag) 
   /declare HaveTarget int local 0
   /declare CastBarTime timer local
   /declare CastCurrLocY float local 0
   /declare CastCurrLocX float local 0
   /varset CastCurrLocY ${Me.Y}
   /varset CastCurrLocX ${Me.X}
   /if (${Target.ID}>0) /varset HaveTarget 1
   /if (!${Defined[CastGiveUpTime]}) /declare CastGiveUpTime timer local 
   /if (!${Defined[ItemFlag]}) /declare ItemFlag string local 
   /if (!${Defined[DismountFlag]}) {
       /declare DismountFlag string local nocheck
       /if (${ItemFlag.Find["dismount"]}) /varset DismountFlag ${ItemFlag}
   }
   /if (!${Me.Standing} && !${Me.Mount.ID}>0) /stand
   /if (${Me.Moving}) { 
       /keypress forward 
       /keypress back 
       /delay 8 
   } else { 
       /delay 4 
   } 
   /if (${ItemFlag.Equal["Item"]} || ${ItemFlag.Equal["Activate"]}) /goto :StartCast 

   /if (!${Me.Gem["${SpellName}"]}) { 
       /if (${ItemFlag.Find[gem]}) {
           /if (${Int[${ItemFlag.Right[1]}]}>0 && ${Int[${ItemFlag.Right[1]}]}<9) {
               /memspell ${ItemFlag.Right[1]} "${SpellName}" 
               /delay 5s 
           } else {
               /goto :GenericMem
           }
       } else {        
           :GenericMem
           /memspell 5 "${SpellName}" 
           /delay 5s 
       }

   } 
   :StartCast 
      /varset CastGiveUpTime 5s 
   :CastNow 
      /if (${ItemFlag.Equal["Item"]}) { 
         /call ClearReturnValue 
         /cast item "${SpellName}" 
      } else /if (${ItemFlag.Equal["Activate"]}) { 
         /call ClearReturnValue 
         /if (!${Me.AltAbilityReady[${SpellName}]}) /return CAST_ABILITYNOTREADY 
         /alt activate ${AltAbility[${SpellName}].ID}
         /varset CastBarTime ${Me.Casting.CastTime}
      } else { 
         /if (!${Me.Gem["${SpellName}"]}) /return CAST_UNKNOWNSPELL 
         /call ClearReturnValue 
         /if (!${Me.SpellReady["${SpellName}"]}) { 
            /if (${CastGiveUpTime}==0) /return CAST_TOOK2LONG 
            /delay 1 
            /goto :CastNow 
         } 
         /cast "${SpellName}" 
         /varset CastBarTime ${Math.Calc[${Me.Casting.CastTime}*10]}
      } 
   :WaitCast 
      /if (${Me.Casting.ID}) { 
         /if ((!${Target.ID}>0 || ${Target.Type.Equal[CORPSE]}) && !${DismountFlag.Find[nocheck]} && ${HaveTarget}==1) {
             /if (${Me.Mount.ID}>0) {
                 /if (${DismountFlag.Equal[dismount]}) {
                     /dismount
                 } else {
                     /if (!${ItemFlag.Equal["Item"]}) {
                         /if (${CastBarTime}<7) {
                             :Interrupt
                             /keypress FORWARD hold
                             /delay 6
                             /keypress FORWARD
                             /keypress BACK hold
                             /delay 8
                             /keypress BACK
                         } else {
                             :HoldForSpell
                             /delay 1
                             /if (${CastBarTime}<7) /goto :Interrupt
                             /goto :HoldForSpell
                         }
                     } else {
                         /keypress FORWARD hold
                         :Forward
                         /delay 1
                         /if (${Math.Distance[${CastCurrLocY},${CastCurrLocX}]}<6) /goto :Forward
                         /keypress FORWARD
                         /keypress BACK hold
                         :Backward
                         /delay 1
                         /if (${Math.Distance[${CastCurrLocY},${CastCurrLocX}]}>4) /goto :Backward
                         /keypress BACK
                         /if (!${Me.Casting.ID}>0) /goto :DuckTime
                     }
                 }
             }
             :DuckTime
             /keypress FORWARD
             /keypress BACK
             /if (!${Me.Ducking}) /keypress DUCK
             /delay 1
             /if (${Me.Ducking}) /keypress DUCK
             /return CAST_LOSTTARGET
         }
         /delay 1
         /goto :WaitCast 
      } 
   /delay 1 
   /doevents Fizzle 
   /doevents Interrupt 
   /doevents Interrupt 
   /doevents Recover 
   /doevents Standing 
   /doevents OutOfRange 
   /doevents OutOfMana 
   /doevents NoLOS 
   /doevents Resisted 
   /doevents ImmuneSlow 
   /doevents Stunned 
   /doevents Collapse 
   /if (${Macro.Return.Equal["CAST_RESTART"]}) /goto :StartCast 
   /if (!${Macro.Return.Equal["NULL"]}) /return ${Macro.Return} 
/return CAST_SUCCESS 

Sub ClearReturnValue 
/return NULL 

Sub Event_Fizzle 
/return CAST_RESTART 

Sub Event_Interrupt 
/return CAST_RESTART 

Sub Event_Recover 
   /delay 5 
/return CAST_RESTART 

Sub Event_Standing 
   /stand 
/return CAST_RESTART 

Sub Event_Collapse 
/return CAST_RESTART 

Sub Event_OutOfMana 
/return CAST_OUTOFMANA 

Sub Event_OutOfRange 
/return CAST_OUTOFRANGE 

Sub Event_NoLOS 
/return CAST_CANNOTSEE 

Sub Event_Stunned 
   /delay 2s !${Me.Stunned} 
/return CAST_RESTART 

Sub Event_Resisted 
/return CAST_RESISTED 

Sub Event_ImmuneSlow 
/return CAST_IMMUNESLOW

Posted: Thu Apr 29, 2004 3:57 pm
by Pax
i cant seem to make it use clickies, tried both with
/call Cast "some item" Item
and
/call Cast "Some item" ItemFlag
am i having a brain fart or is it not working ?

Posted: Thu Apr 29, 2004 4:03 pm
by ml2517
Lol shit.. I did a search and replace at one point which might have broken it. Let me take a look.

Posted: Thu Apr 29, 2004 4:09 pm
by ml2517
Ok give it a shot now, it should function as it always has.

For items:
/call Cast "Spell Name" Item

For AA Skills:
/call Cast "Spell Name" Activate

I'll be adding in logic that uses Lax's new alt ability stuff shortly.

Posted: Thu Apr 29, 2004 4:16 pm
by Pax
there, thanks for the quick fix :)

Posted: Thu Apr 29, 2004 10:36 pm
by ml2517
Updated:
Changed the activate option to use AltAbilityReady instead of an event. If that Ability number isn't ready it will return CAST_ABILITYNOTREADY.

Posted: Sun May 02, 2004 11:39 pm
by ml2517
Updated:
Added the ability to specify a gem slot to mem the spell you are trying to cast, if it is not currently memmed. Previously, it would just shove it on slot 5.

Example: (This would mem to slot 1 if it isn't currently memmed):
/call Cast "Heroic Bond" gem1

Not medding on OOM

Posted: Mon May 10, 2004 6:01 am
by Twister
It dosent seem to be medding on OOM as of the 5/6/04 MQ

Re: Not medding on OOM

Posted: Mon May 10, 2004 6:38 am
by ml2517
Twister wrote:It dosent seem to be medding on OOM as of the 5/6/04 MQ
Umm really? It never did. You must be talking about a different flavor of spellcast.inc.

Posted: Mon May 10, 2004 4:19 pm
by Twister
Ok, Im sorry, I must be, I had a version during the old params that did, I thought this was it.

Posted: Mon May 10, 2004 11:01 pm
by ml2517
Updated:
spellcast.inc

Updated events for new event system.

checking events from events?

Posted: Wed May 12, 2004 5:23 pm
by Chill
I dont know if its possible or not, but Im wondering if you can check events from events?

Im wondering if one could define #event unstunned "#*#You are unstunned#*#", check it from Event_Stunned, and then immediately resume casting from Event_Unstunned when it fired? Might only save half a second, but if its possible why not?

By the way, awesome include. Using it in all my macros for casting.

Posted: Wed May 12, 2004 5:53 pm
by ml2517
Theoretically, yes you can just have it stay in a loop within the stunned sub until the other event fires but I'm not really sure why you would need to do that.

It should keep retrying to cast until you are unstunned as is right? Is that not the case?

Posted: Wed May 12, 2004 5:57 pm
by Chill
I guess I was trying to make it resume casting as soon as someone was unstunned, but I thought of a better way:

Code: Select all

Sub Event_Stunned 
   /delay 2s !{Me.Stunned}
/return CAST_RESTART
It will cut the delay short, as soon as you become unstunned and immediately resume casting.

What happens when your target dies?

Posted: Wed May 12, 2004 7:01 pm
by Chill
One last request would be to interrupt a spell and return a new value when your target dies, to cover situations where someone else kills the mob you're nuking, or the person you're healing dies, or whatever.

I think the change would go here:

Code: Select all

   :WaitCast 
      /if (${Me.Casting.ID}) { 
         /delay 1 
         /goto :WaitCast 
      }
And would look like:

Code: Select all

   :WaitCast 
      /if (${Me.Casting.ID}) {
         /if (${Target.Type.Equal["Corpse"]}) {
            /if (${Me.Buff["Summon Drogmor"].Duration || ${Me.Buff["Summon Horse"].Duration}) {
               /keypress forward hold
               /delay 1
               /keypress back 
            } else
               /keypress duck
               /keypress duck
            }
            /return CAST_TARGETDIED
         }
         /delay 1
         /goto :WaitCast 
      }
But Im wondering if anyone has a better way to go about doing this?
All times are UTC-05:00
Page 1 of 3
Powered by phpBB® Forum Software © phpBB Limited
https://www.phpbb.com/