MacroQuest64

Code: Select all

//==enchbot.mac==\\
//== Xantan's Enchanter C3/keibot -- Do with it what you want ==\\

#turbo

#Event C1 "#1# auctions, '#*#c1#*#"
#Event C1 "#1# says out of character, '#*#c1#*#"
#Event C1 "#1# shouts, '#*#c1#*#"
#Event C1 "#1# auctions, '#*#clarity#*#"
#Event C1 "#1# says out of character, '#*#clarity#*#"
#Event C1 "#1# shouts, '#*#clarity#*#"
#Event C2 "#1# auctions, '#*#c2#*#"
#Event C2 "#1# says out of character, '#*#c2#*#"
#Event C2 "#1# shouts, '#*#c2#*#"
#Event C2 "#1# shouts, '#*#gift of pure thought#*#"
#Event C2 "#1# says out of character, '#*#gift of pure thought#*#"
#Event C2 "#1# auctions, '#*#gift of pure thought#*#"
#Event C3 "#1# auctions, '#*#c3#*#"
#Event C3 "#1# says out of character, '#*#c3#*#"
#Event C3 "#1# shouts, '#*#c3#*#"
#Event C3 "#1# auctions, '#*#kei#*#"
#Event C3 "#1# says out of character, '#*#kei#*#"
#Event C3 "#1# shouts, '#*#kei#*#"
#Event Hail "#1# says, 'Hail, |${Me.Name}|'"
#event Haste "#1# auctions, '#*#haste#*#"
#event Haste "#1# says out of character, '#*#haste#*#"
#event Haste "#1# shouts, '#*#haste#*#"
#event Haste "#1# auctions, '#*#sov#*#"
#event Haste "#1# says out of character, '#*#sov#*#"
#event Haste "#1# shouts, '#*#sov#*#"
#Event Hold "Your spell would not have taken hold on your target."
#Event Oor "Your target is out of range, get closer!"
#Event Spam "You can't use that command while casting..."
#Event Stuck "You can't use that command right now..."

#include Spell_Routines.inc

Sub Main
/declare TargetName string outer
/if (!${Defined[AFKMessage]}) /declare AFKMessage string outer 15% Extended Kei, and or Speed of Vallon @ Main - Bank - Please hail me if you need anything.
/if (!${Defined[MedMessage]}) /declare MedMessage string outer ...Meditating... - please hold till I have mana, then hail me if you need buffs.
/afk ${AFKMessage}
/tgb on
/ooc C3, C2, C1, and Haste @ Main Bank. Hail me for attention.
/echo Started Kei/Haste bot

:MainLoop
/if (!${Me.AFK}) /call AFK
/if (${Me.PctMana} < 40) /call Med
/if (${Window[TradeWnd].Open}) /call Money
/if (${Me.Standing} && !${Me.Mount.ID}) /sit
/doevents
/goto :MainLoop

Sub AFK
/afk ${AFKMessage}
/return

Sub Buff
/if (${Window[TradeWnd].Open}) /call Money
/if (${Spawn[pc ${TargetName}].Pet.ID}) {
/if (${Spawn[PC ${TargetName}].Level} < 46) /tell ${TargetName} Inc SLtW on pet.
/if (${Spawn[PC ${TargetName}].Level} > 45) /tell ${TargetName} Inc SoV on pet.
/call BuffPet
}
/target id ${Spawn[PC ${TargetName}].ID}
/face
/if (${Spawn[PC ${TargetName}].Level} < 46) /tell ${TargetName} Inc SLtW on you.
/if (${Spawn[PC ${TargetName}].Level} > 45) /tell ${TargetName} Inc SoV on you.
/if (${Spawn[PC ${TargetName}].Level} > 45) /call cast "Speed of Vallon" gem5 15s
/if (${Spawn[PC ${TargetName}].Level} < 46) /call cast "Swift Like the Wind" gem4 15s
/if (${Spawn[PC ${TargetName}].Level} < 42) /call C1
/if (${Spawn[PC ${TargetName}].Level} > 41 && ${Spawn[PC ${TargetName}].Level} < 45) /call C2
/if (${Spawn[PC ${TargetName}].Level} > 44) /call C3
/return

Sub BuffPet
/if (${Window[TradeWnd].Open}) /call Money
/target ${Spawn[PC ${TargetName}].Pet}
/face
/if (${Spawn[PC ${TargetName}].Level} > 45) /call cast "Speed of Vallon" gem5 15s
/if (${Spawn[PC ${TargetName}].Level} < 46) /call cast "Swift Like the Wind" gem4 15s
/return

Sub C1
/if (${Window[TradeWnd].Open}) /call Money
/face
/tell ${TargetName} INC C1 - click off oldies
/call cast "Boon of the Clear Mind" gem1 15s
/return

Sub C2
/if (${Window[TradeWnd].Open}) /call Money
/face
/tell ${TargetName} INC C2 - click off oldies
/call cast "Gift of Pure Thought" gem2 15s
/return

Sub C3
/if (${Window[TradeWnd].Open}) /call Money
/face
/tell ${TargetName} INC C3 - click off oldies
/call cast "Koadic's Endless Intellect" gem3 15s
/return

Sub FaceSouthEast
/if (${Window[TradeWnd].Open}) /call Money
/face loc 390.98, 390.27
/delay 1s
/return

Sub Med
/afk ${MedMessage}
/if (!${Me.Sitting} && !${Me.Mount.ID}) /sit on
/delay 5m ${Me.PctMana} > 60
/afk ${AFKMessage}
/return

Sub Money
/delay 3s ${Window[TradeWnd].Open}
/delay 3s ${Window[TradeWnd].HisTradeReady}
/if (${Window[TradeWnd].HisTradeReady}) {
/echo Received a donation from ${Target.CleanName}.
/notify TradeWnd TRDW_Trade_Button leftmouseup
/say Thank you for your donation, ${Target.CleanName}. Hail me if you need buffs still.
}
/delay 1s
/return

Sub Oor
/t ${TargetName} ${Target.CleanName} is out of range, please come closer if you need buffs.
/return

Sub Event_C1(Line,Sender)
/if (${Window[TradeWnd].Open}) /call Money
/delay 2s
/if (${Spawn[PC ${Sender}].Class.ShortName.Equal[ENC]}) /return
/delay 1s
/tell ${Sender} Clarity 1+ @ MB - hail me.
/return

Sub Event_C2(Line,Sender)
/if (${Window[TradeWnd].Open}) /call Money
/delay 2s
/if (${Spawn[PC ${Sender}].Class.ShortName.Equal[ENC]}) /return
/delay 1s
/tell ${Sender} Clarity 2+- @ MB - hail me.
/return

Sub Event_C3(Line,Sender)
/if (${Window[TradeWnd].Open}) /call Money
/delay 2s
/if (${Spawn[PC ${Sender}].Class.ShortName.Equal[ENC]}) /return
/delay 1s
/tell ${Sender} Kei[c3-] + (haste) @ Main Bank - cmon down hail me.
/return

Sub Event_Hail(Line,Sender)
/varset TargetName ${Sender}
/if (${Me.Sitting}) /stand up
/if (${Window[TradeWnd].Open}) /call Money
/delay 2
/target id ${Spawn[PC ${TargetName}].ID}
/call Buff
/call FaceSouthEast
/return

Sub Event_Haste(Line,Sender)
/if (${Window[TradeWnd].Open}) /call Money
/delay 2s
/if (${Spawn[PC ${Sender}].Class.ShortName.Equal[ENC]}) /return
/delay 1s
/tell ${Sender} SoV or SLTW (haste) @ Main Bank - cmon down hail me.
/return

Sub Event_Hold
/t ${TargetName} The spell I casted wouldn't take hold, please click off old buffs and hail me again if you'd like to be buffed.
/return

Sub Event_Oor
/t ${TargetName} ${Target.CleanName} is out of range, please come closer if you need buffs.
/return

Sub Event_Spam
/delay 4s
/return

Sub Event_Stuck
/say sec
/notify TradeWnd TRDW_Cancel_Button leftmouseup
/return