MacroQuest64

Code: Select all

;Wait4rez.iss v2.2
;Translated for ISXEQ by echoism
;based on A_Druid_00's Wait4Rez.inc
#if ${Script.Filename.Equal[wait4rez]}
function main()
{
	call Wait4Rez()	
}
#endif

function Wait4Rez()
{
	echo Awaiting rez: auto-accepting, and looting my corpse
	while !${Window[ConfirmationDialogBox].Open}
		WaitFrame
	Window[ConfirmationDialogBox].Child[Yes_Button]:LeftMouseUp
	while !${Spawn[corpse,${Me.Name}].ID}
		WaitFrame
	while ${Target.CleanName.NotEqual[${Me}'s corpse]}
		Target corpse ${Me.Name}
	while ${Me.Spawn.State.NotEqual[BIND]}
	{
		if (${Target.Distance}>20) 
			EQExecute /corpse
		Wait 50 ${Target.Distance}<20
		if ${Target.Distance}>100
			return
		EQExecute /loot
		Wait 50 ${Me.Spawn.State.Equal[BIND]}
	}
	DeclareVariable loottotal int local
	while ${Corpse.Items}
	{
		loottotal:Set[${Corpse.Items}]
		Wait 10 ${loottotal}!=${Corpse.Items}
	}
	DeclareVariable i int local 0
	while ${i:Inc} <= ${loottotal}
	{
		while ${Corpse.Item[${i}].ID}
		{
			EQItemNotify loot${i} rightmouseup
			Wait 100 !${Corpse.Item[${i}].ID}
		}
	}
	Window[LootWnd].Child[DoneButton]:LeftMouseUp
}

Code: Select all

   while ${Target.CleanName.NotEqual[${Me}'s corpse]}
      Spawn[corpse,${Me.Name}]:Target 

Code: Select all

   while ${Target.CleanName.NotEqual[${Me}'s corpse]}
      Target corpse ${Me.Name}

Code: Select all

objectdef scripttimer
{ 
	variable uint EndTime 
	method Set(uint Milliseconds) 
	{ 
		EndTime:Set[${Milliseconds}+${MacroQuest.Running}] 
	} 
	member:uint TimeLeft()
	{ 
		if ${MacroQuest.Running}>=${EndTime} 
			return 0 
		return ${Math.Calc[${EndTime}-${MacroQuest.Running}]} 
	}
	member:uint ToText()
	{ 
		if ${MacroQuest.Running}>=${EndTime} 
			return 0 
		return ${Math.Calc[(${EndTime}-${MacroQuest.Running})/1000].Int} 
	}
} 

variable bool haveacorpse=FALSE
variable scripttimer corpsetimer
variable int i

function main()
{

	echo Awaiting rez: auto-accepting, and looting my corpse
	AddTrigger countingcorpse "You have given @p1@ permission to drag your corpse in @p2@."
	EQExecute /consent ${Me.CleanName}${Me.CleanName}
	timedcommand 25 EQExecute /deny ${Me.CleanName}${Me.CleanName}
	corpsetimer:Set[10000]
	while !${haveacorpse} && ${corpsetimer}
	{
		if ${QueuedCommands}
			ExecuteQueued
		else
			WaitFrame
	}

	while 1
	{
		if !${haveacorpse}
		{
			break
		}
		if !${Me.Gem[1](exists)} && !${Window[LootWnd]}
		{
			EQExecute /memspellset cr
			wait 300 ${Me.Gem[9](exists)}
		}
		if ${Window[ConfirmationDialogBox].Open} && !${Me.Buff[1].Name.Find[Resurrection]}
		{
			Window[ConfirmationDialogBox].Child[Yes_Button]:LeftMouseUp
		}
		if ${Spawn[corpse,${Me.Name}].ID} && ${Spawn[corpse,${Me.Name}].Distance}<100
		{
			Target "${Me}'s corpse"
			wait 50  ${Target.CleanName.Equal[${Me}'s corpse]}
		}
		if ${Target.CleanName.Equal[${Me}'s corpse]} && ${Spawn[corpse,${Me.Name}].Distance}>9
		{
			EQExecute /corpse
			wait 50 ${Spawn[corpse,${Me.Name}].Distance}>9
		}

		if ${Target.CleanName.Equal[${Me}'s corpse]} && ${Spawn[corpse,${Me.Name}].Distance}<10
		{
			EQExecute /loot
			wait 50 ${Window[LootWnd]}
		}

		if ${Window[LootWnd]}
		{
			wait 50 ${Window[LootWnd].Child[LW_LootSlot0].Tooltip.Length}>0
			for (i:Set[0] ; ${i}<31 ; i:Inc)
			{
				if ${Window[LootWnd].Child[LW_LootSlot${i}].Tooltip.Length}>0
				{
					Window[LootWnd].Child[LW_LootSlot${i}]:RightMouseUp
					wait 30 ${Window[LootWnd].Child[LW_LootSlot${i}].Tooltip.Length}==0
				}
			}
			Window[LootWnd].Child[DoneButton]:LeftMouseUp
			break
		}
		if ${QueuedCommands}
			ExecuteQueued
		else
			WaitFrame
	}
}

function countingcorpse(string Line,... params)
{
	haveacorpse:Set[TRUE]
}