adv_fishing.mac (Advanced Fishing Macro. v1.0beta 01/07/04)

[ionsf]

I love fishing macros... especially ones that use Fisherman's Companion. Panther, your macro will be included with the future release of MQ2. Good commentation at the beginning and through out the entire macro. I saw nothing but praise about this macro, and it gets my blessing.

One request... between casts, make it clicky "Brell's Fishin' Pole" and drink the summoned Ale. =)

I liked this idea.

Here is the code with it. You will need spell_routine.inc which is in this form.

Panther you did a great job on this mac.

Also you will become quite drunk. I put in some information that lets you know how drunk you are and how long until you sober up.

Also I made it so that you do not camp until you can walk straight.

Code: Select all

|--------------------------------------------------------------------------------- 
| Advanced Fishing Macro 
| adv_fishing.mac 
| Author      : panther 
| Version     : v1.0beta 2004-07-01 18:58pm GMT 
| Useage      : /macro adv_fishing 
| Description : 
| This macro will fish for you and keep all items in FishingLoot.ini. You need a 
| fisherman's companion in an inventory slot for this macro to work properly. 
|--------------------------------------------------------------------------------- 

#turbo 10 
#include spell_routines.inc

#event BrokenPole "Your fishing pole broke!" 
#event LostBait "You lost your bait!" 
#event NeedPole "You can't fish without a fishing pole, go buy one." 
#event NothingCaught "You didn't catch anything." 
#event OutOfBait "You can't fish without fishing bait, go buy some." 
#event PrimaryHand "You need to put your fishing pole in your primary hand." 
#event SkillUp "You have become better at Fishing #1#! (#2#)" 
#event SpillBeer "You spill your beer while bringing in your line." 

Sub Main 

   |------------------------------------------------------------ 
   |Should I display fishing stats? (1 for yes, 0 for no) 
   |------------------------------------------------------------ 
   /declare RV_DisplayStats     int outer  1 


   /echo Starting up ${Macro} 
   /declare int_BrokenPole     int outer  0 
   /declare int_ItemsDropped     int outer  0 
   /declare int_LostBait     int outer  0 
   /declare int_NothingCaught     int outer  0 
   /declare int_SpillBeer     int outer  0 
   /declare int_TotalCasts     int outer  0 
   /declare int_TotalAle	int outer 0
   /declare drunksecs int  outer
   |------------------------------------------------------------ 
   |Load in Loot Table. 
   |------------------------------------------------------------ 
   /call ReadINI FishingLoot.ini "${Zone.Name}" Loot 
   /if (!${Defined[RV_LootArray]}) { 
      /echo No Loot Table Created... Please create one. 
      /endmacro 
   } 

   /autoinventory 

   :Start 
      /call GMCheck 
      /delay 2s 
      /if (${Cursor.ID}) /call Looting 
      /if (${Me.AbilityReady[Fishing]}) { 
         /delay 1s 
         /varcalc int_TotalCasts ${int_TotalCasts}+1 
         /doability Fishing 
      } 
      /doevents 
   /goto :Start 
/return 


|-------------------------------------------------------------------------------- 
|SUB: Display fishing stats. 
|-------------------------------------------------------------------------------- 
Sub DisplayStats 

   /declare nArray  int local 
   /echo Total number of casts = ${int_TotalCasts} 
   /echo Total Ale's this trip = ${int_TotalAle}
   /echo Items fished so far 
   /echo ------------------- 
   /if (${Defined[RV_LootArray]}) { 
      /for nArray 1 to ${RV_LootArray.Size} 
         /echo ${Int[${RV_LootStats[${nArray}]}]} - ${RV_LootArray[${nArray}]}'s 
      /next nArray 
   } 
   /echo 
   /echo Bad fishing so far 
   /echo ------------------ 
   /echo ${int_BrokenPole} - Broken poles 
   /echo ${int_ItemsDropped} - Items dropped 
   /echo ${int_LostBait} - Lost bait 
   /echo ${int_NothingCaught} - Nothing caught 
   /echo ${int_SpillBeer} - Spilt your beer 
/return 

|-------------------------------------------------------------------------------- 
|SUB: Check for GM's in zone. 
|-------------------------------------------------------------------------------- 
Sub GMCheck 

   /if (${Spawn[gm].ID}) { 
      /beep 
      /beep 
      /beep 
      /echo GM entered the zone! 
      /echo For safty reasons ending the macro... 
      /endmacro 
   } 

/return 

|-------------------------------------------------------------------------------- 
|SUB: Looting based on FishingLoot.ini. 
|-------------------------------------------------------------------------------- 
Sub Looting 

   /declare LootCheck   int inner  0 

   /for LootCheck 1 to ${RV_LootArray.Size} 
      /if (${Cursor.Name.Find[${RV_LootArray[${LootCheck}]}]}) { 
         /echo Keeping a ${Cursor.Name}... WOOT! 
	 /echo How bout a beer?
         /varcalc RV_LootStats[${LootCheck}] ${RV_LootStats[${LootCheck}]}+1 
         /autoinventory 
	 /call Rewardme
      } 
   /next LootCheck 

   /if (${Cursor.ID}) { 
      /echo Dropping a ${Cursor.Name}... 
      /drop 
      /varcalc int_ItemsDropped ${int_ItemsDropped}+1 
   } 

   /if (${RV_DisplayStats}) /call DisplayStats 
/return 

|-------------------------------------------------------------------------------- 
|SUB: Read loot table from the INI file. 
|-------------------------------------------------------------------------------- 
Sub ReadINI(FileName,SectionName,ArrayType) 

   /echo Attempting to Read Section "${SectionName}" Zone Information from ${FileName}... 
   /delay 1s 

   /if (${Ini[${FileName},${SectionName},-1,NO].Equal[NO]}) { 
      /echo "${SectionName}" is not a Valid Section for FILE:${FileName}, ending macro... 
      /delay 1s 
      /return 
   } 
   /declare nValues     int local  1 
   /declare nArray      int local  0 
   /declare KeySet      string local  ${Ini[${FileName},${SectionName}]} 

   :CounterLoop 
   /if (${Ini[${FileName},${SectionName},${ArrayType}${nValues},NULL].Equal[NULL]}) { 
      /varcalc nValues ${nValues}-1 
      /goto :MakeArray 
   } 
      /varcalc nValues ${nValues}+1 
   /goto :CounterLoop 

   :MakeArray 
   /if (!${nValues}) /return 
   /if (${FileName.Equal["FishingLoot.ini"]}&&${nValues}>0) { 
      /echo Declaring Loot Array... 
      /declare RV_LootArray[${nValues}]  string outer 
      /declare RV_LootStats[${nValues}]  string outer 
   } 

   /for nArray 1 to ${nValues} 
      /if (${FileName.Equal["FishingLoot.ini"]}) { 
         /varset RV_LootArray[${nArray}] ${Ini[${FileName},${SectionName},${ArrayType}${nArray}]} 
         /varset RV_LootStats[${nArray}] 0 
      } 
   /next nArray 

   /echo "${SectionName}" Zone Information Read Successfully from ${FileName}... 
   /delay 1s 

/return 


|--------------------------------------------------------------------------------
|SUB: Rewards for catching --  Credit for this code goes to A_Druid_00
|			      I just grabbed it and modified it.
|--------------------------------------------------------------------------------
Sub Rewardme
	/call Cast "Brell's fishin' Pole" item
|--------------------------------------------------------------------------------
| Find and then Drink our new reward
|--------------------------------------------------------------------------------
	/declare mypack         string local 
	/declare myslot         string local 
	/declare i              int    local 
	/declare foodcount      int    local 
	/declare food       string local 

	/autoinventory 
	/if (${Cursor.ID}) /return 
		/for i 1 to 1
		/varset food "Summoned: Ale" 
	/if (${FindItemCount[${food}]}>0) { 
		/varset mypack ${FindItem[${food}].InvSlot.Pack} 
		/varset myslot ${FindItem[${food}].InvSlot} 
	/if (${mypack}) { 
	/if (!${Window[${InvSlot[${mypack}].Name}].Open}) /nomodkey /itemnotify ${mypack} rightmouseup 
		:WaitForBagOpen 
		/nomodkey /ctrl /itemnotify ${myslot} leftmouseup 
	/if (!${Cursor.ID}) /goto :WaitForBagOpen 
		/nomodkey /itemnotify ${mypack} leftmouseup 
		/nomodkey /itemnotify ${mypack} rightmouseup 
		/nomodkey /itemnotify ${mypack} leftmouseup 
	} else { 
		/nomodkey /itemnotify ${myslot} rightmouseup 
	} 
	} else { 
		/next i 
	} 
	/varcalc int_TotalAle ${int_TotalAle}+1
	/declare pctdrunk	int local
	/echo You are ${Math.Calc[${Me.Drunk}/2]}% drunk.
	/varset drunksecs ${Math.Calc[${Me.Drunk}*6]}
	/echo It will take you ${Math.Calc[${drunksecs}/60]} minutes to sober up
/return 	



|-------------------------------------------------------------------------------- 
|SUB: Event subroutines. 
|-------------------------------------------------------------------------------- 
Sub Event_BrokenPole 
   /varcalc int_BrokenPole ${int_BrokenPole}+1 
   /varcalc int_NothingCaught ${int_NothingCaught}-1 
/return 

Sub Event_LostBait 
   /varcalc int_LostBait ${int_LostBait}+1 
   /varcalc int_NothingCaught ${int_NothingCaught}-1 
/return 

Sub Event_NeedPole 
   /cast item "Fisherman's Companion" 
   /delay 11s 
   /autoinventory 
/return 

Sub Event_NothingCaught 
   /varcalc int_NothingCaught ${int_NothingCaught}+1 
/return 

Sub Event_OutOfBait 
   /Echo Ran out of Bait. 
   /if (${Me.Drunk}>100) {
	/varset drunksecs ${Math.Calc[${Me.Drunk}*6]}
	/echo I'm waaay to drunk to put up my tent.
	/echo I'm gonna wait ${Math.Calc[${drunksecs}/60]} minutes while I sober up.
	/delay ${Math.Calc[${drunksecs}/60]}m
	/echo Ohhhh my head!
	/delay 2
	/echo Did I blackout? Get me to a bed.
    }
    /if (${Me.Drunk}>40) {
	/varset drunksecs ${Math.Calc[${Me.Drunk}*6]}
	/echo I'm a little to drunk to prepare my camp
	/echo I'm going to wait ${Math.Calc[${drunksecs}/60]} minutes.
	/delay ${Math.Calc[${drunksecs}/60]}m
	/echo Yawn. I feel much better. Lets make camp and go to sleep.
    }
   /sit off 
   /sit on 
   /camp 
   /endmacro 
/return 

Sub Event_PrimaryHand 
   /cast item "Fisherman's Companion" 
   /delay 11s 
   /autoinventory 
/return 

Sub Event_SkillUp(SkillUpText,Skill,int Amount) 
   /popup Fishing increased to - ${Amount} 
   /echo Fishing increased to - ${Amount} 
/return 

Sub Event_SpillBeer 
   /varcalc int_SpillBeer ${int_SpillBeer}+1 
   /varcalc int_NothingCaught ${int_NothingCaught}-1 
/return 

[tuzlo]

Whenever I have an item in hand and I go to cast again, this macro CTD.

[tekno]

works for me - thanks

[beergod]

has anyone got a way to add the usage of the Anizok's Bait dispenser to these? (fishing Macs) baisicly it takes certine fish and combines them to mkae homemade bait, which will stack to 250, it's kind of a tradeskill container, but there is no search feature, or autoinventory, all you can do is hit combine, one fish at a time

[PhoenixZorn]

ionsf,

Nice addition to the macro... I know I'm a bit behind the times, but someone finally did what I asked. Very well done on the camping after stability, and the drunkedness reports. I was thinking about this the other day, and being drunk actually helps you avoid being kicked for AFK or through player tells that would normally result in a GM Petition about AFK fishermen... If you are drunk, and have even just a few pre-made auto responses to tells while drunk, no one will have any clue what you are saying anyway, so they'll think you are just a drunken fisherman...

Maybe. =)

[Eandiien]

wasnt putting bags back in inventory when done drinking this saved me cause all my bags were no drop. how ever added a fix for this which is harmeless if you dont have the same issue.

Code: Select all

Sub Rewardme 
   /call Cast "Brell's fishin' Pole" item 
|-------------------------------------------------------------------------------- 
| Find and then Drink our new reward 
|-------------------------------------------------------------------------------- 
   /declare mypack         string local 
   /declare myslot         string local 
   /declare i              int    local 
   /declare foodcount      int    local 
   /declare food       string local 

   /autoinventory 
   /if (${Cursor.ID}) /return 
      /for i 1 to 1 
      /varset food "Summoned: Ale" 
   /if (${FindItemCount[${food}]}>0) { 
      /varset mypack ${FindItem[${food}].InvSlot.Pack} 
      /varset myslot ${FindItem[${food}].InvSlot} 
   /if (${mypack}) { 
   /if (!${Window[${InvSlot[${mypack}].Name}].Open}) /nomodkey /itemnotify ${mypack} rightmouseup 
      :WaitForBagOpen 
      /nomodkey /ctrl /itemnotify ${myslot} leftmouseup 
   /if (!${Cursor.ID}) /goto :WaitForBagOpen 
      /nomodkey /itemnotify ${mypack} leftmouseup 
      /nomodkey /itemnotify ${mypack} rightmouseup 
      /nomodkey /itemnotify ${mypack} leftmouseup 
   } else { 
      /nomodkey /itemnotify ${myslot} rightmouseup 
   } 
   } else { 
      /next i 
   } 
   [color=red]/delay 2s
   /autoinventory[/color]
   /varcalc int_TotalAle ${int_TotalAle}+1 
   /declare pctdrunk   int local 
   /echo You are ${Math.Calc[${Me.Drunk}/2]}% drunk. 
   /varset drunksecs ${Math.Calc[${Me.Drunk}*6]} 
   /echo It will take you ${Math.Calc[${drunksecs}/60]} minutes to sober up 
/return     

[eqgirl]

Ok...after desperately searching for a fishing macro..this is exactly what i need...however...I am too much of a noob to know exactly how to load this to be able to use it. Will someone please hold my hand and guide me?:) i know how to create the ini ...thanks to the forage mac...I just need help adding it to use it and the commands to turn it off and on:) I know...alot to ask

[Eandiien]

there should be an ini for this some were in the post. if not search for fishingloot.ini that should help you out some. as for as howt o work it si simple place your fishermans companion in an upper slot ie not in a bag and free up your primary slot. then type. /macro advfish and away it goes if you do not have an ini it will tell you so. the .ini is simple too it is organized by zones. and under each zone is what you want to keep. i'll post my .ini here just incase you have trouble it is easier that way.

Code: Select all

[the Abysmal Sea] 
Loot1=1 lb. Saltwater Crab 
Loot2=1 lb. Saltwater Tuna 
Loot3=10 lb. Saltwater Crab 
Loot4=10 lb. Saltwater Tuna 
Loot5=11 lb. Saltwater Crab 
Loot6=11 lb. Saltwater Tuna 
Loot7=12 lb. Saltwater Crab 
Loot8=12 lb. Saltwater Tuna 
Loot9=13 lb. Saltwater Crab 
Loot10=13 lb. Saltwater Tuna 
Loot11=14 lb. Saltwater Crab 
Loot12=14 lb. Saltwater Tuna 
Loot13=15 lb. Saltwater Crab 
Loot14=15 lb. Saltwater Tuna 
Loot15=2 lb. Saltwater Crab 
Loot16=2 lb. Saltwater Tuna 
Loot17=3 lb. Saltwater Crab 
Loot18=3 lb. Saltwater Tuna 
Loot19=4 lb. Saltwater Crab 
Loot20=4 lb. Saltwater Tuna 
Loot21=5 lb. Saltwater Crab 
Loot22=5 lb. Saltwater Tuna 
Loot23=6 lb. Saltwater Crab 
Loot24=6 lb. Saltwater Tuna 
Loot25=7 lb. Saltwater Crab 
Loot26=7 lb. Saltwater Tuna 
Loot27=8 lb. Saltwater Crab 
Loot28=8 lb. Saltwater Tuna 
Loot29=9 lb. Saltwater Crab 
Loot30=9 lb. Saltwater Tuna 

[Ak'Anon] 
Loot1=clockwork koi 

[Blackburrow] 
Loot1=hound pike 

[Butcherblock Mountains] 
Loot1=stonefish 

[Chardok] 
Loot1=chokai bass 

[City of Mist] 
Loot1=fogwater trout 
Loot2=ikfish 

[Crushbone] 
Loot1=boar carp 

[Crystal Caverns] 
Loot1=crystalline cave fish 

[Cobaltscar] 
Loot1=Cobalt Cod 
Loot2=dragon bay snapper 

[Dagnor's Cauldron] 
Loot1=cauldron trout 

[Deepest Guk] 
Loot1=cave guppy 
Loot2=eyeless whitefish 
Loot3=muckskipper 
Loot4=fish slime 
Loot5=covered planarian 

[Dulak] 
Loot1=abalone 
Loot2=frilled anemone 
Loot3=sea cucumber 

[East Cabilis] 
Loot1=10lb fetid bass 
Loot2=11lb fetid bass 
Loot3=12lb fetid bass 
Loot4=13lb fetid bass 
Loot5=14lb fetid bass 
Loot6=15lb fetid bass 
Loot7=16lb fetid bass 
Loot8=17lb fetid bass 
Loot9=2lb fetid bass 
Loot10=3lb fetid bass 
Loot11=4lb fetid bass 
Loot12=5lb fetid bass 
Loot13=6lb fetid bass 
Loot14=7lb fetid bass 
Loot15=8lb fetid bass 
Loot16=9lb fetid bass 
Loot17=giant fetid bass 
Loot18=gigantic fetid bass 
Loot19=humongous fetid bass 
Loot20=large fetid bass 
Loot21=large fetid bass 
Loot22=large fetid bass 
Loot23=large fetid bass 
Loot24=salt minnow sewer 
Loot25=catfish tiny 
Loot26=fetid bass 

[East Karana] 
Loot1=thunder salmon 

[Eastern Wastes] 
Loot1=rygorrian toothfish 

[Erud's Crossing] 
Loot1=barren flounder 

[Feerrott] 
Loot1=thullian mudskipper 

[Firiona Vie] 
Loot1=10lb fetid bass 
Loot2=11lb fetid bass 
Loot3=12lb fetid bass 
Loot4=13lb fetid bass 
Loot5=14lb fetid bass 
Loot6=15lb fetid bass 
Loot7=16lb fetid bass 
Loot8=17lb fetid bass 
Loot9=2lb fetid bass 
Loot10=3lb fetid bass 
Loot11=4lb fetid bass 
Loot12=5lb fetid bass 
Loot13=6lb fetid bass 
Loot14=7lb fetid bass 
Loot15=8lb fetid bass 
Loot16=9lb fetid bass 
Loot17=giant fetid bass 
Loot18=gigantic fetid bass 
Loot19=humongous fetid bass 
Loot20=large fetid bass large 
Loot21=fetid bass 
Loot22=large fetid bass 
Loot23=salt minnow sewer 
Loot24=catfish 
Loot25=tiny fetid bass 

[the Gulf of Gunthak] 
Loot1=deep sea urchin 
Loot2=gunthak gourami 
Loot3=moray eel 
Loot4=ovate jellyfish 


[Highpass Hold] 
Loot1=highland pike 

[Hollowshade Moor] 
Loot1=fish scales 
Loot2=fresh fish 
Loot3=rusty dagger 

[Iceclad Ocean] 
Loot1=iceclad cutlassfish 
Loot2=salty whitefish 

[Innothule Swamp] 
Loot1=rujarkian chub 
Loot2=thullian mudskipper 

[Jaggedpine Forest] 
Loot1=thunder salmon 

[Kael Drakkel] 
Loot1=frosty cave trout 

[Karnor's Castle] 
Loot1=wulf fish 

[Kedge Keep] 
Loot1=kedge carp 

[Kerra Ridge] 
Loot1=kerra catfish 

[Lake Rathetear] 
Loot1=rathe muskie 

[Mines of Nurga] 
Loot1=cave guppy 
Loot2=sponge mushroom 

[Natimbi] 
Loot1=1 lb. Saltwater Crab 
Loot2=1 lb. Saltwater Tuna 
Loot3=2 lb. Saltwater Crab 
Loot4=2 lb. Saltwater Tuna 
Loot5=3 lb. Saltwater Crab 
Loot6=3 lb. Saltwater Tuna 
Loot7=4 lb. Saltwater Crab 
Loot8=4 lb. Saltwater Tuna 
Loot9=5 lb. Saltwater Crab 
Loot10=5 lb. Saltwater Tuna 
Loot11=Ginseng 

[Nedaria's Landing] 
Loot1=thunder salmon 
Loot2=fish scales

[Neriak - Commons] 
Loot1=Fresh Fish 
Loot2=Fish Scales 


[North Felwithe] 
Loot1=koada cichlid 

[North Karana] 
Loot1=thunder salmon 

[Ocean of Tears] 
Loot1=gunthak mackerel 
Loot2=saltwater 
Loot3=seaweed 

[The Plane of Disease] 
Loot1=diseased fish 

[The Plane of Nightmares] 
Loot1=Fresh Fish 
Loot2=Fish Scales 
Loot3=Crawdad 
Loot4=Waterleaf Scale 
Loot5=Nightmare Cichlid 

[The Plane of Storms] 
Loot1=storm salmon 

[The Plane of Tranquility] 
Loot1=quellian koi 
Loot2=waterleaf scale 
Loot3=worn turban 

[The Plane of Valor] 
Loot1=Fresh Fish 
Loot2=Fish Scales 
Loot3=Crawdad 
Loot4=Vallorian Discus 

[The Plane of Water] 
Loot1=giant halibut 
Loot2=giant snapper 

[Rujarkian Hills] 
Loot1=cave guppy 

[Siren's Grotto] 
Loot1=grotto bluegill 

[Sleeper's Tomb] 
Loot1=weary wrass 

[South Felwithe] 
Loot1=koada cichlid 

[South Karana] 
Loot1=thunder salmon 

[Surefall Glade] 
Loot1=pine cichlid 

[Swamp of No Hope] 
Loot1=despair chub 
Loot2=krup guppy 

[The Overthere] 
Loot1=danak grouper 

[The Ruins of Old Paineel] 
Loot1=hatch dace 

[The Ruins of Sebilis] 
Loot1=kunzar koi 

[Timorous Deep] 
Loot1=saltwater seaweed 
Loot2=timorous tuna 

[Togiran Mines] 
Loot1=bay seaweed 
Loot2=blowfish barb 
Loot3=gunthak gourami 

[Toxxulia Forest] 
Loot1=greengill salmon 

[Txevu] 
Loot1=10 lb. Saltwater Crab 
Loot2=11 lb. Saltwater Crab 
Loot3=11 lb. Saltwater Tuna 
Loot4=12 lb. Saltwater Tuna 
Loot5=7 lb. Saltwater Crab 
Loot6=7 lb. Saltwater Tuna 
Loot7=8 lb. Saltwater Crab 
Loot8=8 lb. Saltwater Tuna 
Loot9=9 lb. Saltwater 
Loot10=Tuna 
Loot11=fish scales 
Loot12=rusty dagger 

[Warslik's Woods] 
Loot1=evergreen salmon 

[West Cabilis] 
Loot1=10lb fetid bass 
Loot2=11lb fetid bass 
Loot3=12lb fetid bass 
Loot4=13lb fetid bass 
Loot5=14lb fetid bass 
Loot6=15lb fetid bass 
Loot7=16lb fetid bass 
Loot8=17lb fetid bass 
Loot9=2lb fetid bass 
Loot10=3lb fetid bass 
Loot11=4lb fetid bass 
Loot12=5lb fetid bass 
Loot13=6lb fetid bass 
Loot14=7lb fetid bass 
Loot15=8lb fetid bass 
Loot16=9lb fetid bass 
Loot17=giant fetid bass 
Loot18=gigantic fetid bass 
Loot19=humongous fetid bass 
Loot20=large fetid bass 
Loot21=sewer catfish 
Loot22=tiny fetid bass 

[West Karana] 
Loot1=thunder salmon 

[Western Wastes] 
Loot1=red roughy 

[Eandiien]

add this following evet
it will take care of those pesky lore items but please understand it will destroy things that is why there is a warning and a timer in there for you to inventory manually. please use caution with this

Eandiien

Code: Select all

#event lore "that item cannot be dropped, traded, or sold."

Sub Event_lore
   /beep
   /beep
   /beep
   /echo you have 20 seconds to save this item or it will be destroyed
   /popup you have 20 seconds to save this item or it will be destroyed
   /delay 25s
   /destroy
/return

[Yunto?]

...

Thats the text for a no drop item when you try to hand it to someone.

[fearless]

wow, what a colossally bad idea.

[Fuergrissa]

wow, what a colossally bad idea.

I don't think that word describes it enough !!!!!!

I would advise EVERYBODY to NEVER NEVER use a destroy of ANY sort in any Macro, after destroying my druid epic once.

[Eandiien]

i sopose i could have specified if holding stupid abysmal key then destroy but this just seemed easy and quick. i tried to make it safe as i could hwo ever it is designed that you dont wonder away from your comp. if you do wonder which i'm sure most of us do then make sure you dont have kids in the house that could accidently target and destroy something. any how . on a side note watch out for temporary bags you know the summoned ones i to deleated my sham epic cause it was in a summoned bag. but that wasnt with a mac.

Eandiien

[simkin]

What I did when I re-wrote hyperfish was add a [destroy] section that only deletes cursor items that match ones listed. This way people can list anything they want and be protected.

[Yunto?]

i sopose i could have specified if holding stupid abysmal key then destroy but this just seemed easy and quick. i tried to make it safe as i could hwo ever it is designed that you dont wonder away from your comp. if you do wonder which i'm sure most of us do then make sure you dont have kids in the house that could accidently target and destroy something. any how . on a side note watch out for temporary bags you know the summoned ones i to deleated my sham epic cause it was in a summoned bag. but that wasnt with a mac.

Eandiien

No, you dont understand. Your event had absolutely nothing to do with an item being LORE. Any item that was NO DROP, if it was being clicked in the air to drop, would trigger that even. Droppable LORE items wouldnt trigger it. The event doesnt do what you want it to.